CheckExternalScripts: check_users_loggedin.vbs

'########################################################################
'# Name: Michel van Son (michelvs@phison.nl)                                                    #
'# Company: Phison Technologies                                                                                 #
'# Date: 12-02-2010                                                                                                             #
'# Purpose: External check script to get number of users logged in              #
'# Changes: [dd-mm-yyyy] Name | changes                                                                 #
'########################################################################

'################################################################################################################
'# Without arguments, the script will only return the number of users logged in with exit code 0                                #
'# When supplying arguments, the first argument is the warning treshold and the second is the critical treshold #
'# More or less then 2 arguments will result in an error with status Unknown(3)                                                                 #
'################################################################################################################

Option Explicit

'Declare variables.
Dim valWarning
Dim valCritical
Dim objWMIService
Dim objUsers
Dim valUsers


'Check for arguments.
if Wscript.Arguments.Count > 0 then
        if Wscript.Arguments.Count > 2 then
                Wscript.Echo "Too many arguments given. Please enter warning and critical tresholds."
                Wscript.Quit(3)
        elseif Wscript.Arguments.Count < 2 then
                Wscript.Echo "Too few arguments given. Please enter warning and critical tresholds."
                Wscript.Quit(3)
        else
                valWarning = Wscript.Arguments.Item(0)
                valCritical = Wscript.Arguments.Item(1)
                valWarning = CInt(valWarning)
                valCritical = CInt(valCritical)
        end if
end if

'Query the WMI service for the users.
'Use 2 WHERE clauses for Interactive(2) and RemoteInteractive(10) logons.
'More information: http://msdn.microsoft.com/en-us/library/aa394189%28VS.85%29.aspx
Set objWMIService = GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\localhost\root\cimv2")
Set objUsers = objWMIService.ExecQuery ("Select * from Win32_LogonSession Where LogonType = 2 OR LogonType = 10")
valUsers = objUsers.Count
valUsers = CInt(valUsers)

'Check the user count, echo it and exit with proper exitcode.
if valUsers > 0 then
        if Not IsEmpty(valCritical) then
                if valUsers >= valCritical then
                        Wscript.Echo "Critical: Users logged in: " & valUsers & "|'users'=" & valUsers & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(2)
                elseif valUsers >= valWarning then
                        Wscript.Echo "Warning: Users logged in: " & valUsers & "|'users'=" & valUsers & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(1)
                else
                        Wscript.Echo "OK: Users logged in: " & valUsers & "|'users'=" & valUsers & ";" & valWarning & ";" & valCritical
                        Wscript.Quit(0)
                end if
        else
                Wscript.Echo "OK: Users logged in: " & valUsers & "|'users'=" & valUsers
                Wscript.Quit(0)
        end if
else
        Wscript.Echo "OK: No users logged in.|'users'=" & valUsers
        Wscript.Quit(0)
end if